summaryrefslogtreecommitdiff
path: root/src/thread/powerpc64/clone.s
blob: 41cb6787a7bca59a9f0ff5e3545b8cf992b67bff (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
.text
.global __clone
.hidden __clone
.type __clone, %function
__clone:
	# int clone(fn, stack, flags, arg, ptid, tls, ctid)
	#            a  b       c     d     e    f    g
	#            3  4       5     6     7    8    9
	# pseudo C code:
	# tid = syscall(SYS_clone,c,b,e,f,g);
	# if (!tid) syscall(SYS_exit, a(d));
	# return tid;

	# create initial stack frame for new thread
	clrrdi 4, 4, 4
	li     0, 0
	stdu   0,-32(4)

	# save fn and arg to child stack
	std    3,  8(4)
	std    6, 16(4)

	# shuffle args into correct registers and call SYS_clone
	mr    3, 5
	#mr   4, 4
	mr    5, 7
	mr    6, 8
	mr    7, 9
	li    0, 120  # SYS_clone = 120
	sc

	# if error, negate return (errno)
	bns+  1f
	neg   3, 3

1:	# if we're the parent, return
	cmpwi cr7, 3, 0
	bnelr cr7

	# we're the child. call fn(arg)
	ld     3, 16(1)
	ld    12,  8(1)
	mtctr 12
	bctrl

	# call SYS_exit. exit code is already in r3 from fn return value
	li    0, 1    # SYS_exit = 1
	sc