summaryrefslogtreecommitdiff
path: root/src/fenv/i386/fenv.s
blob: 72d2ed7dbbb0057ec408dade62422dabd090f655 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
2:	not %ecx
	sub $32,%esp
	fnstenv (%esp)
	and %ecx,4(%esp)
	or %edx,4(%esp)
	fldenv (%esp)
	add $32,%esp
	ret

.global feclearexcept
feclearexcept:	
	xor %eax,%eax
	mov 4(%esp),%ecx
	xor %edx,%edx
	test %ecx,%ecx
	jnz 2b
	ret

.global feraiseexcept
feraiseexcept:	
	xor %eax,%eax
	mov 4(%esp),%edx
	xor %ecx,%ecx
	test %edx,%edx
	jnz 2b
	ret

.global fesetround
fesetround:
	xor %eax,%eax
	mov $0xc00,%ecx
	mov 4(%esp),%edx
	jmp 2b

.global fegetround
fegetround:
	sub $28,%esp
	fnstenv (%esp)
	mov 4(%esp),%eax
	add $28,%esp
	and $0xc,%ah
	ret

.global fegetenv
fegetenv:
	mov 4(%esp),%ecx
	xor %eax,%eax
	fnstenv (%ecx)
	ret

.global fesetenv
fesetenv:
	mov 4(%esp),%ecx
	xor %eax,%eax
	test %ecx,%ecx
	jz 1f
	fldenv (%ecx)
	ret
1:	push %eax
	push %eax
	push %eax
	push %eax
	push %eax
	push %eax
	pushl $0x37f
	fldenv (%esp)
	add $28,%esp
	ret

.global fetestexcept
fetestexcept:
	mov 4(%esp),%ecx
	fnstsw %ax
	and %ecx,%eax
	ret